これらの関係演算子を使用して，プログラム内の変数に対する「条件式」を記述してみます．

整数の変数 x の内容が５以上かどうか（５以上のとき真）：x >= 5
整数の変数 x の内容が５かどうか（５のとき真）：x = 5
doubleの変数 x の内容が3.5より小さいかどうか（3.5未満のとき真）：x < 3.5

二つの条件式をそれぞれ A，B とすると．次のような論理演算子と組み合わせることで２つの条件式を組合せた条件式を記述できます．また，これらの論理演算子を複数使用し，２つ以上の条件式を多様に組み合わせることで，様々に組み合わされた複雑な条件式を記述することが可能です．

論理演算の結果を表したものを「真理値表」と言い，それぞれの論理演算子によって，組み合わされる条件式の個々の真偽がどのように組み合わされるかを示しています．

これらの論理演算子を使用して，複雑な条件式を記述できます．

整数の変数 x の内容が５以上かつ10未満かどうか（５以上かつ10未満のとき真）：x >= 5 And x < 10
整数の変数 x の内容が５ではなく，整数の変数 y の内容が３かどうか（xが５でなくyが３のとき真）：Not x = 5 And y = 3
doubleの変数 x の内容が 3.5 より小さいまたは，doubleの変数 y の内容が 7.5 より大きいかどうか：x < 3.5 Or y > 7.5

各自，様々な条件をどのように記述すれば良いかを考えてみましょう．論理演算子で結合した条件式は，基本的に左辺から順に評価されますが，括弧()で囲えば，その部分が先に評価されます．

条件が成立するときだけ処理を実行するには，次のような「If ~ Then」と言う構造を使用します．

If 条件式 Then

  処理

End If
        

このように書くと，「条件式」が「真」のときだけ「処理」が実行されます．

得点がセルA2に入力されていて，得点が６０点以上の時，セルB2に「合格」の判定を表示するプログラム

Sub gokaku()

  Dim tokuten As Integer    '変数tokutenを整数として宣言
  
    tokuten = Range("A2").Value   '得点を変数に代入

    '分岐処理

    If tokuten >= 60 Then

      Range("B2").Value = "合格"

    End If

End Sub
  

条件によって処理を分けるプログラムの構造．

If 条件式 Then

  処理１

Else

  処理２

End If
        

このように書くと，「条件式」が「真」のときは「処理１」が，「偽」のときは「処理２」が実行されます．

数値がセルA2に入力されていて，数値が偶数か奇数かを判定し，結果をB2に表示するプログラム

Sub even_odd()

  Dim n As Integer    '変数nを整数として宣言
  
    n = Range("A2").Value   '数値を変数に代入
          
    '分岐処理
          
    If n Mod 2 = 0 Then
          
      Range("B2").Value = "偶数"
  
    Else

      Range("B2").Value = "奇数"
          
    End If
          
End Sub
          

複数の条件を順番に適用し，成立する条件ごとに異なる処理を実行するプログラムの構造．

If 条件式１ Then

  処理１

ElseIf 条件式２ Then

  処理２

Else

  処理３

End If
        

このように書くと，「条件式１」が「真」のときは「処理１」が，「条件式１」が「偽」で「条件式２」が「真」のときは「処理２」を，「条件式２」も「偽」であれば「処理３」が実行されます．さらに条件と処理がある場合は「ElseIf 条件式 Then 処理」の部分を繰り返します．

セルA2に入力した数値が，まず３の倍数かどうか判定し，３の倍数でない場合は５の倍数かどうかを判定して，結果を入力した数値の右に表示するプログラム

Sub hantei()

  Dim n As Integer    '変数nを整数として宣言
  
    n = Range("A2").Value   '数値を変数に代入
                    
  '分岐処理
                    
    If n Mod 3 = 0 Then
                    
      Range("B2").Value = "３の倍数です"
            
    ElseIf n Mod 5 = 0 Then
          
      Range("B2").Value = "３の倍数ではない５の倍数です"
                    
    Else

      Range("B2").Value = "３の倍数でも５の倍数でもありません"
  
    End If

End Sub
          

コードウィンドウでプログラム ex_031x の下に新しい Sub プロシージャ「ex_032a」を作成します．
セルに入力した数値が，１３で割り切れるかどうかを判定し，さらに割り切れる場合はそれが３の倍数かどうかを判定するプログラムを作ってみましょう．結果は数値を入力したセルの右のセルに表示しましょう．分かりやすくするために，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．プログラムはボタンに登録し，ボタンは ex_031x の横に適当な間隔を開けて配置してください．

コードウィンドウでプログラム ex_031x の下に新しい Sub プロシージャ「ex_032b」を作成します．
セルに入力した数値が，３で割って余りが１かどうかを判定し，さらに１余る場合はそれが５の倍数かどうか，余りが１でない場合はそれが７の倍数かどうかを判定するプログラムを作ってみましょう．結果は数値を入力したセルの右のセルに表示しましょう．分かりやすくするために，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．プログラムはボタンに登録し，ボタンは ex_031x の横に適当な間隔を開けて配置してください．

コードウィンドウでプログラム ex_031xの下に新しい Sub プロシージャ「ex_032c」を作成します．
セルに図形の種類「球，円柱，円錐」と底面の半径と高さ（球の場合は半径だけ）を入力し，図形の種類に応じてその表面積と体積を計算させて入力したセルの下のセルに表示するプログラムを作ってみましょう．分かりやすくするために，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．プログラムはボタンに登録し，ボタンは ex_031x の横に適当な間隔を開けて配置してください．

多数の条件を判定して，成立する条件ごとに異なる処理をするプログラムの構造．

Select Case 変数

  Case 条件１

    処理１

  Case 条件２

    処理２

  Case 条件３

    処理３

  Case Else

    処理４

End Select
        

このように書くと，「変数」に対して上から順に「条件N」を判定し，成立した条件の「処理N」を実行します．どの条件にも当てはまらない場合は最後の「Case Else」の処理が実行されます．

変数の値に対して，様々な場合に対応する条件は次のように記述します．

A2セルに数値を入力するとB2セルに上記の条件に対応した表示が出力されるプログラムを書いてみます．

Sub hantei2()

  Dim kazu As Integer    '変数 kazu を宣言

    kazu = Range("A2").Value   '数値を変数に代入

    '分岐処理

    Select Case kazu

      Case 5

        Range("B2").Value = "入力は５です"

      Case Is >= 20

        Range("B2").Value = "入力は２０以上です"

      Case Is < 8

        Range("B2").Value = "入力は８未満です"

      Case 10 To 15

        Range("B2").Value = "入力は１０以上１５以下です"

      Case Else

        Range("B2").Value = "入力は条件外です"

    End Select

End Sub