処理した回数を数える「カウンタ変数」を用意し，カウンタ変数の最初の値「初期値」と終了する値「終値」，数え方「増分（変化量）」を設定してカウントしながら処理を実行します．増分を負の値にして減らしながらカウントすることも可能です．また，増分が１の場合には Step の部分を省略できます．

For カウンタ変数 = 初期値 To 終値 Step 増分

  処理

Next カウンタ変数
          

２つの数値を入力し，片方には２を足し，もう片方は２を掛ける作業を１０回繰り返し，さらにそれぞれの初期値から１０回計算した後までの和を求めるプログラムを作ります．出力は，繰り返しの回数とその時の数値を表示し，最後に和を出力させます．A1セルに回数の文字が入力されているとします．また，セルの位置を指定するために数値を使用したいので，セルの操作に Range ではなく Cells を使用しています．

Sub kyusu_wa()

  '変数宣言
  Dim i As Integer, n As Integer, m As Integer    '各回の値を表す
  Dim sum1 As Integer, sum2 As Integer    '和を計算する
              
    '入力された数値を代入
    n = Cells(2,2).Value
    m = Cells(2,3).Value

    '和の初期値を設定
    sum1 = n
    sum2 = m
              
    '反復処理；For文
    For i = 1 To 10
              
      '計算
      n = n + 2
      m = m * 2

      '和の計算
      sum1 = sum1 + n
      sum2 = sum2 + m
    
      '各回の結果をセルに表示
      Cells(2+i,1).Value = i
      Cells(2+i,2).Value = n
      Cells(2+i,3).Value = m
              
    Next i

    '和を表示
    Cells(i+3,1).Value = "合計"
    Cells(i+3,2).Value = sum1
    Cells(i+3,3).Value = sum2

End Sub
          

For ~ Next を入れ子にして使用することで２重，３重の繰り返しを記述できます．

ここでは１から４０までの掛け算の表を作成するプログラムを作ってみます．出力は新しいワークシートを作成してそこに表示します．

Sub kakezan()

  '変数宣言
  Dim i As Integer, j As Integer
  Dim mySheet As Worksheet

    'ワークシートオブジェクトの設定（右側に「掛算表」という名前で追加）
    set mySheet = Worksheets.Add(After:=Worksheets(3))
    mySheet.Name = "掛算表"
                          
    '反復処理；For文
    For i = 1 To 40
  
      For j = 1 To 40

        '各回の結果をセルに表示
          mySheet.Cells(i,j).Value = i*j
                          
      Next j
  
    Next i

End Sub
            

セルに初項と公差を入力し，等差数列の１０項目までを表示するプログラムを作りましょう．結果は初項を入力したセルの下のセルに表示するようにし，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．Sheet3にフォームコントロールのボタンを挿入し，プログラムを登録して名前をex_041aに変えて下さい，ボタンはシートの左上あたりに配置してください．

セルに初項と公比を入力し，等比数列の１０項目までの和を計算して表示するプログラムを作りましょう．結果は初項を入力したセルの下のセルに表示するようにし，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．Sheet3にフォームコントロールのボタンを挿入し，プログラムを登録して名前をex_041bに変えて下さい，ボタンはシートの左上あたりに配置してください．

注意：整数型（Integer）は 32767 までの整数しか扱えないので，数列の和がそれを超えるような場合はエラーになってしまいます．これを回避する為には，変数の型を「Long（長整数型）」に変更します．

セルに積分範囲の始点と終点，分割数を入力し，\(f(x) = \mathrm{e}^{-x^2}\) の定積分を求めるプログラムを作りましょう．結果は範囲を入力したセルの下のセルに表示するようにし，使用するセルはこのプログラムを登録するボタンの下に来る位置のセルにしてください．Sheet3にフォームコントロールのボタンを挿入し，プログラムを登録して名前をex_041cに変えて下さい，ボタンはシートの左上あたりに配置してください．

関数の定積分はある範囲で関数のグラフの面積を求めることです．これをコンピューター上で実現するには，関数の変数の範囲を細かく分割し，その分割幅と各分割点での関数の値を高さとした長方形の集合に面積の合計を計算することによって定積分の近似値とします．分割数を大きくする程正確な値に近くなります．正確な計算では，\(\int_{-\infty}^{\infty}\mathrm{e}^{-x^2}dx = \sqrt{\pi}\)．

Excelのブックは「Workbook」オブジェクトで，存在するブック全体は「Workbooks」コレクションです．同様に，Excelのシートは「Worksheet」オブジェクト，シート全体は「Worksheets」コレクション，Excelの各セルは「Range」オブジェクトでセルの範囲は「Range」コレクションとなります．

For Each オブジェクト変数 In コレクション
  処理
Next オブジェクト変数
          

A1セルに数値を入力し，上記の例の「掛算表」の中で入力した数値の倍数のセルの色を変えるプログラムを作ってみます．

Sub cell_color()

  Dim myRange As Range
  Dim n As Integer

  n = Range("A1").Value

  For Each myRange In Worksheets("掛算表").Range("B2:AO41")

    If myRange.Value Mod n = 0 Then myRange.Interior.Color = 65535

  Next

End Sub
          

最初に条件式を判定してから処理を実行します．従って，１回も処理を実行しないこともあります．

Do Until 条件式
  処理
Loop
          

セルに数値を入力し，フィボナッチ数列の値が入力した数値を超えた時の項数と値を表示する．

フィボナッチ数列とは，\(i\)項目の値を\(F_i\)と書いたとき，最初の２項の値を \(F_0 = 0\)，\(F_1 = 1\) として次のようにして得られる数列です． \[ F_{i+2} = F_i + F_{i+1} \]

Sub fibonacci()
              
  Dim f0 As Integer, f1 As Integer, f2 As Integer
  Dim i As Integer, n As Integer
              
    n = Range("A2").Value
    i = 0
    f0 = 0
    f1 = 1
    f2 = 0
              
    Do Until f2 > n
                  
      f2 = f0 + f1
              
      f0 = f1
      f1 = f2
      
      i = i + 1
              
    Loop
            
    Range("B2").Value = i
    Range("C2").Value = f2
              
End Sub
            

処理を実行してから条件式を判定します．従って，少なくとも１回は処理を実行します．

Do
  処理
Loop Until 条件式
          

セルに年利を入力し，複利計算で元利合計が元金の２倍になる期間を求める

複利とは，次の期間の利息を元金と前期間の利息の合計に対して利率をかけて計算する方式です．

Sub fukuri()
          
  Dim kikan As Integer
  Dim gankin As Long, risoku As Long, gokei As Long
  Dim nenri As Single
            
    nenri = Range("A2").Value
    gankin = Range("B2").Value
    kikan = 0
    risoku = 0
    gokei = gankin
            
    Do
          
      risoku = gokei * riritu / 100
      gokei = gokei + risoku
            
      kikan = kikan + 1
             
    Loop Until gokei > 2 * gankin
            
    Range("C2").Value = gokei
    Range("D2").Value = kikan
            
End Sub
                      

最初に条件式を判定してから処理を実行します．従って，１回も処理を実行しないこともあります．

Do While 条件式
  処理
Loop
          

処理を実行してから条件式を判定します．従って，少なくとも１回は処理を実行します．

Do 
  処理
Loop While 条件式
          

基本的には Until の場合と同じで，条件の設定が逆になるだけです．したがって，具体的な例は示しませんので，自分で Until の例を While に書き直してみましょう．

For 
  処理
  If 条件式 Then Exit For
Next
                      

Do 
  処理
  If 条件式 Then Exit Do 
Loop
          

入力した整数 n が素数かどうかを判定するプログラムを考えてみます．2 から始めて √n までの数で割り切れるかどうかを判定します．繰り返しは割り切れたところで終了して結果を表示します．

Sub sosu_hantei()

  Dim n As Integer
  Dim i As Integer
  Dim hantei As Boolean

    n = Range("A1").Value

    hantei = True

    For i = 2 To Sqr(n)

      If n Mod i = 0 Then

        hantei = False

        Exit For

      End If
        
    Next i

    If hantei Then

      Range("B1").Value = "素数です"

    Else

      Range("B1").Value = "素数ではありません"

    End If

End Sub